int rows = 10;      //number of rows of squares to draw in the background
int cols = 10;      //number of columns of squares to draw in the background 
int flakes = 80;    //number of snowflakes to draw in the foreground


int[][] aSquare = new int[rows*cols][3];    //array to hold x, y, and shade values for each square
int[][] aFlake = new int[flakes][4];        //array to hold starting x, y, and size and speed scale values for each flake
Square[] oSquare = new Square[rows*cols];   //array to hold each square object
Flake[] oFlake = new Flake[flakes];         //array to hold each flake object


void setup() {
  size(300,300);
  framerate(30);
  fillSquareArray();
  fillFlakeArray();
  makeObjects();
  smooth();
}

void draw() {
  for(int i=0;i<oSquare.length;i++) {
    oSquare[i].refresh();
  }
  for(int i=0;i<flakes;i++) {
    oFlake[i].refresh();
  }
}

void fillSquareArray() {    //fills the "aSquare" array with values for x, y, and shade for each square
  for(int i=0; i<aSquare.length; i++) {
    aSquare[i][1] = height/rows * int(i/rows);
    aSquare[i][0] = width/cols * i - aSquare[i][1]*cols;
    aSquare[i][2] = int(random(80,180));
  }
}

void fillFlakeArray() {    //fills the "aFlake" array with values for starting x and y and scale for each flake
  for(int i=0; i<flakes; i++) {
    aFlake[i][0] = int(random(0, width));    //randomly-selected starting x position
    aFlake[i][1] = int(random(0, height)) - 30;   //randomly-selected starting y position
    aFlake[i][2] = int(random(3, 9));        //randomly-selected size scale factor
    aFlake[i][3] = int(random(2, 6));        //randomly-selected speed scale factor
  }
}

void makeObjects () {
  for(int i=0; i<oSquare.length; i++) {
    oSquare[i] = new Square(aSquare[i][0], aSquare[i][1], aSquare[i][2]);
  }
  for(int i=0; i<flakes; i++) {
    oFlake[i] = new Flake(aFlake[i][0], aFlake[i][1], aFlake[i][2], aFlake[i][3]);
  }
}

class Square {
  int xPos;
  int yPos;
  int Shade;
  int Increment = 1;
 
  Square(int _x, int _y, int _s) {
    xPos = _x;
    yPos = _y;
    Shade = _s;
  }
  
  void refresh() {
    fill(Shade, 200);
    noStroke();
    rect(xPos, yPos, width/cols, height/rows);
    Shade = Shade + Increment;
    if(Shade <= 60) {
      Increment = 2;
    } 
    if(Shade >= 180) {
      Increment = -2;
    }
  }
}


class Flake {
  int xPos;
  int yPos;
  int Scale;
  int Speed;
  int xAdjust;
  
  Flake(int _x, int _y, int _s, int _d) {
    xPos = _x;
    yPos = _y;
    Scale = _s;
    Speed = _d;
    if(noise(yPos)<.4) {
      xAdjust = -1;
    } else if(noise(yPos)>.6) {
      xAdjust = 1;
    } else {
      xAdjust = 0;
    }
  }
  
  void refresh() {
    stroke(255,160);
    fill(255,160);
    ellipse(xPos, yPos, Scale*4, Scale*4);
    yPos = yPos+Speed;
    if((dist(xPos, yPos, mouseX, mouseY) < 60) && (xPos >= mouseX)) {
      xPos = xPos + 5;
    } else if((dist(xPos, yPos, mouseX, mouseY) < 60) && (xPos < mouseX)) {
      xPos = xPos - 5;
    }
    if((dist(xPos, yPos, mouseX, mouseY) < 60) && (yPos >= mouseY)) {
      yPos = yPos + 5;
    } else if((dist(xPos, yPos, mouseX, mouseY) < 60) && (yPos < mouseY)) {
      yPos = yPos - 5;
    }

    xPos = xPos + xAdjust;
    if(yPos-Scale*3 >= height) {
      yPos = -50;
      xPos = int(random(0, width));
      Scale = int(random(3, 9));  
      Speed = int(random(2, 6));
    }
  }
}