PImage deskPic;
AnalogClock clock;
String readings[];
int counter = 0;
int tintVal = 0;
int h, m, s;
int graphValues[];
int graphPoints[];

void setup() {
  deskPic = loadImage("desk.jpg");
  size(deskPic.width,deskPic.height);
  framerate(30);
  clock = new AnalogClock(100);
  readings = loadStrings("catted.txt");
  buildGraph();
  smooth();
}

void draw() {
  if(mousePressed) {
    background(0);
    stroke(255);
    strokeWeight(1);
    for(int i=0; i<graphPoints.length; i++) {
      point(i,height-graphPoints[i]-height/4);
    }
    int interval = int(graphValues.length/width);    
    line(counter/interval,0,counter/interval,height);
  } else {
    background(0);
    updateDisplay();
    tint(tintVal);
    image(deskPic,0,0);
    pushMatrix();
      translate(width - (clock.clockSize/2),clock.clockSize/2);
      clock.refresh(h,m,s);
    popMatrix();  
  }
}

void buildGraph() {
  graphValues = new int[readings.length];
  for(int i=0; i<graphValues.length; i++) {
    int readingStart = readings[i].indexOf("-") + 1;
    int readingStop = readings[i].length();
    int value = int(readings[i].substring(readingStart,readingStop));
    graphValues[i] = value;
  }
  int interval = int(graphValues.length/width);
  graphPoints = new int[width];
  for(int i=0; i<graphPoints.length; i++) {
    graphPoints[i] = graphValues[i*interval];
  }
}

void updateDisplay() {
  if(counter < readings.length) {
    int hourStart = 0;
    int hourStop = readings[counter].indexOf(":");
    int minuteStart = hourStop + 1;
    int minuteStop = readings[counter].indexOf(":",minuteStart);
    int secondStart = minuteStop + 1;
    int secondStop = readings[counter].indexOf("-",secondStart);
    int readingStart = secondStop + 1;
    int readingStop = readings[counter].length();
    h = int(readings[counter].substring(hourStart,hourStop));
    m = int(readings[counter].substring(minuteStart,minuteStop));
    s = int(readings[counter].substring(secondStart,secondStop));
    tintVal = int(readings[counter].substring(readingStart,readingStop));
    //    println(tintVal);
    counter += 10;
  } 
  else {
    counter = 0;
  }
}

class AnalogClock {
  int hourHand, minuteHand, secondHand;
  float clockSize;

  AnalogClock(float _cs) {
    clockSize = _cs;
  }

  void refresh(int _h, int _m, int _s) {
    hourHand = _h;
    minuteHand = _m;
    secondHand = _s;
    drawClockFace();
    drawTickMarks();
    drawMinuteHand();
    drawHourHand();
//    drawSecondHand();    
  }

  void drawTickMarks() {
    for(int i=0; i<12; i++) {
      float endX = (clockSize/2) * cos(radians(i * 30));
      float endY = (clockSize/2) * sin(radians(i * 30));
      float startX = (0.85 * clockSize/2) * cos(radians(i * 30));
      float startY = (0.85 * clockSize/2) * sin(radians(i * 30));
      strokeWeight(4);
      stroke(0);
      line(startX,startY,endX,endY);
    }
  }

  void drawClockFace() {
    noStroke();
    fill(255);
    ellipse(0,0,clockSize,clockSize);
  }

  void drawMinuteHand() {
    float endX = (0.75 * clockSize/2) * cos(radians(minuteHand * 6 - 90));
    float endY = (0.75 * clockSize/2) * sin(radians(minuteHand * 6 - 90));
    strokeWeight(2);
    stroke(0);
    line(0,0,endX,endY);
  }

  void drawHourHand() {
    float endX = (0.5 * clockSize/2) * cos(radians(hourHand * 30 - 90));
    float endY = (0.5 * clockSize/2) * sin(radians(hourHand * 30 - 90));
    strokeWeight(4);
    stroke(0);
    line(0,0,endX,endY);
  }

  void drawSecondHand() {
    float endX = (0.75 * clockSize/2) * cos(radians(secondHand * 6 - 90));
    float endY = (0.75 * clockSize/2) * sin(radians(secondHand * 6 - 90));
    strokeWeight(1);
    stroke(255,0,0);
    line(0,0,endX,endY);
  }
}